在ABAP Webdynpro里显示PDF的一种办法

There is a good blog about how to get PDF preview in CRM web client UI. However several development are invovled in that solution. You have to implement your own ICF node to make PDF displayed in UI, and you have to generate the binary code of PDF by yourself.

There is just another approach to achieve the same result but with much less coding by leveraging the standard control “Adobe Interactive form” in ABAP webdynpro. In this way no ICF node implementation, no manual PDF binary code generation, just a few model task.

(1) Create an form interface in tcode SFP.

Choose interface type as ABAP Dictionary-Based Interface.

Just create two parameter NAME and SCORE. Activate the interface.

(2) Create a new form template via tcode SFP.

Click “Context”tab, drag the two parameters from Interface to the right part Context ZPF_EXAMPLE and drop there.

Click tab Layout, design your form layout. Here I create a caption and two text fields. Bind the data source of the two fields to your form context parameter. Here text field NAME is bound to ZPF_EXAMPLE.NAME and Score field bound to ZPF_EXAMPLE.SCORE.

(3) Create a new ABAP webdynpro in SE80. A view MAIN will be created by workbench automatically. Just put a new Adobe Interactive form control into the empty view. You can choose “Insert Element” from context menu and choose “Interactive form”

Specify the form template name ZPF_EXAMPLE to property “templateSource” created in step2.

After that the property “dataSource” is also determined automatically.

Click tab “Context”, now you should see the two parameters defined in form interface is also displayed in context node of view MAIN.

(4) Create a new Webdynpro application and assign two parameter NAME and SCORE to it.

(5) Double click WDDOINIT to implement:

The init method will retrieve name and score from application parameter included in url. The url will be populated from CRM webclient UI side. Till now the development of ABAP webdynpro is finished. You don’t care about the PDF generation and display, it will be handled by ABAP webdynpro framework.

method WDDOINIT .
  data(lo_node) = wd_context->get_child_node( 'ZPF_EXAMPLE' ).
  DATA: lv_name type string,
        lv_score type int4.
  lv_name = cl_wd_runtime_services=>get_url_parameter( name = 'NAME' ).
  lv_score = cl_wd_runtime_services=>get_url_parameter( name = 'SCORE' ).
  lo_node->set_attribute( name = 'NAME' value = lv_name ).
  lo_node->set_attribute( name = 'SCORE' value = lv_score ).
endmethod.

(6) The left task would be quite easy for a CRM UI developer: I create a simple view with two input fields for Name and Score, and one hyperlink.

The event handler for hyperlink click:

DATA: lr_popup    TYPE REF TO if_bsp_wd_popup,
        lr_cn       TYPE REF TO cl_bsp_wd_context_node,
        lr_obj      TYPE REF TO if_bol_bo_property_access,
        lt_parameters TYPE tihttpnvp,
        ls_params   TYPE crmt_gsurlpopup_params.
  data(lo_data) = me->typed_context->data->collection_wrapper->get_current( ).
  DATA(ls_line) = VALUE ihttpnvp( name = 'NAME' value = lo_data->get_property_as_string( 'NAME' ) ).
  APPEND ls_line TO lt_parameters.
  ls_line = VALUE ihttpnvp( name = 'SCORE' value = lo_data->get_property_as_string( 'VALUE' ) ).
  APPEND ls_line TO lt_parameters.
  cl_wd_utilities=>construct_wd_url(
      EXPORTING
        application_name = 'ZADOBEFORM'
        in_parameters    = lt_parameters
      IMPORTING
        out_absolute_url = mv_url ).
  lr_popup =  me->comp_controller->window_manager->create_popup(  iv_interface_view_name = 'GSURLPOPUP/MainWindow'
                                                                  iv_usage_name          = 'GSURLPOPUP'
                                                                  iv_title               = 'Adobe Interactive Form Control' ).
  lr_cn = lr_popup->get_context_node( 'PARAMS' ).           "#EC NOTEXT
  lr_obj = lr_cn->collection_wrapper->get_current( ).
  ls_params-url = mv_url.
  ls_params-height = '700'.                                 "#EC NOTEXT
  lr_obj->set_properties( ls_params ).
  lr_popup->set_display_mode( if_bsp_wd_popup=>c_display_mode_plain ).
  lr_popup->set_window_width( 700 ).
  lr_popup->set_window_height( 700 ).
  lr_popup->open( ).

Of course you need to add component GSURLPOPUP via component usage. In the runtime after name and score fields are maintained in CRM UI and hyperlink is clicked, the corresponding PDF will be generated and displayed by ABAP Webdynpro framework.

要获取更多Jerry的原创文章，请关注公众号"汪子熙":