剖析Defi之Uinswap_1

学习UniswapERC20,它是交易对的父合约。UniswapV2ERC20 是流动性代币合约，也称为 LP Token。功能主要实习ERC20代币功能以及对线下签名授权。

pragma solidity =0.5.16;

import './interfaces/IUniswapV2ERC20.sol';
import './libraries/SafeMath.sol';

contract UniswapV2ERC20 is IUniswapV2ERC20 {
    using SafeMath for uint;

    string public constant name = 'Uniswap V2';
    string public constant symbol = 'UNI-V2';
    uint8 public constant decimals = 18;
    uint  public totalSupply;
    mapping(address => uint) public balanceOf;
    mapping(address => mapping(address => uint)) public allowance;

    bytes32 public DOMAIN_SEPARATOR;
    // keccak256("Permit(address owner,address spender,uint256 value,uint256 nonce,uint256 deadline)");
    bytes32 public constant PERMIT_TYPEHASH = 0x6e71edae12b1b97f4d1f60370fef10105fa2faae0126114a169c64845d6126c9;
    mapping(address => uint) public nonces;

    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    constructor() public {
        uint chainId;
        assembly {
            chainId := chainid
        }
        DOMAIN_SEPARATOR = keccak256(
            abi.encode(
                keccak256('EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)'),
                keccak256(bytes(name)),
                keccak256(bytes('1')),
                chainId,
                address(this)
            )
        );
    }

    function _mint(address to, uint value) internal {
        totalSupply = totalSupply.add(value);
        balanceOf[to] = balanceOf[to].add(value);
        emit Transfer(address(0), to, value);
    }

    function _burn(address from, uint value) internal {
        balanceOf[from] = balanceOf[from].sub(value);
        totalSupply = totalSupply.sub(value);
        emit Transfer(from, address(0), value);
    }

    function _approve(address owner, address spender, uint value) private {
        allowance[owner][spender] = value;
        emit Approval(owner, spender, value);
    }

    function _transfer(address from, address to, uint value) private {
        balanceOf[from] = balanceOf[from].sub(value);
        balanceOf[to] = balanceOf[to].add(value);
        emit Transfer(from, to, value);
    }

    function approve(address spender, uint value) external returns (bool) {
        _approve(msg.sender, spender, value);
        return true;
    }

    function transfer(address to, uint value) external returns (bool) {
        _transfer(msg.sender, to, value);
        return true;
    }

    function transferFrom(address from, address to, uint value) external returns (bool) {
        if (allowance[from][msg.sender] != uint(-1)) {
            allowance[from][msg.sender] = allowance[from][msg.sender].sub(value);
        }
        _transfer(from, to, value);
        return true;
    }

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external {
        require(deadline >= block.timestamp, 'UniswapV2: EXPIRED');
        bytes32 digest = keccak256(
            abi.encodePacked(
                '\x19\x01',
                DOMAIN_SEPARATOR,
                keccak256(abi.encode(PERMIT_TYPEHASH, owner, spender, value, nonces[owner]++, deadline))
            )
        );
        address recoveredAddress = ecrecover(digest, v, r, s);
        require(recoveredAddress != address(0) && recoveredAddress == owner, 'UniswapV2: INVALID_SIGNATURE');
        _approve(owner, spender, value);
    }
}

  1  第一行指明Solidity版本。

 2 第三、四行, 导入需要实现的接口IUniswapV2ERC20合约，SafeMath 。SafeMath 是用来更安全的处理数据。防止数据溢出 。

3  第六行:创建合约UniswapV2ERC20 实现IUniswapV2ERC20接口

4 第七行:uint类型实现SafeMath库。使用方法 using  xx for xxx

5  第9-11：定义代币的名字 符号 精度。

6 第十二行:定义代币发现总量。

7 第十三行:用mapping 记录地址的代币余额

8 第十四行：mapping 记录地址的授权。

9 第十六行: 区分在不同Dapp之间相同结构和内容签名消息。使用户分辨。

10 第十七行: 根据事先使用permit函数 定义计算哈希值,重建消息签名

11 第十九行:记录地址使用链下签名消息交易的数量,防止重放攻击

12  第二十一二十二行:定义两个事件便于检索 approve事件(发起者，消费者,交易额).transfer转账事件(发送者,接收者,金额)

13 二十四行开始为构造器 计算 DOMAIN_SEPARATOR 的值。

           1) 定义变量 chainid

　　　2）内联汇编赋值  

　　　3）keccak256 哈希运算，abi.encode 计算参数的ABI编码，EIP712Domain  有四个参数，name:可读签名域名称(代币名称),version 可读签名域版本。chainId  当前链ID，verifyingContract 验证合约的地址。.

14  _mint函数，代币增发。

  function _mint(address to, uint value) internal {
        totalSupply = totalSupply.add(value);
      balanceOf[to] = balanceOf[to].add(value);
        emit Transfer(address(0), to, value);
    }
 

       函数参数to(接受地址) value(增加数量）修饰符 internal  外部无法调用。

          1)totalSupply 代币总量增加，接受账户代币增加。触发转移事件。

15  _burn  燃烧函数,和上面_mint函数类似，totalSupply 总量减少,指定用户代币减少,触发转移事件。

16  _approve 授权函数 函数修饰符private,   allowance[owner][spender] = value;触发授权事件

17 _transfer  转移函数 ，修饰符private ，发起者代币减少,接受者地址代币增加。触发转移事件。

18  approve 授权函数，修饰符 external，外部可调用，返回值布尔,调用_approve函数。

19  transfer 转移函数,修饰符 external,外部可调用,返回值布尔类型,调用_transfer函数

20  代表授权转移函数,修饰符external,返回值布尔类型。

 function transferFrom(address from, address to, uint value) external returns (bool) {
         if (allowance[from][msg.sender] != uint(-1)) {
             allowance[from][msg.sender] = allowance[from][msg.sender].sub(value);
         }
         _transfer(from, to, value);
        return true;
    }

   如果授权额度是最大值,uniswapV2中 为减少gas,不会在授权中减少代币数量，如果不是则会减少授权的代币数量,然后调用_transfer 转移函数.

21 permit 使用线下签名消息进行授权操作.UniswapV2 使用线下签名消息主要消除代币授权转移时对授权交易的需求。

  function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external {
         require(deadline >= block.timestamp, 'UniswapV2: EXPIRED');
         bytes32 digest = keccak256(
             abi.encodePacked(
                 '\x19\x01',
                 DOMAIN_SEPARATOR,
                 keccak256(abi.encode(PERMIT_TYPEHASH, owner, spender, value, nonces[owner]++, deadline))
             )
         );
         address recoveredAddress = ecrecover(digest, v, r, s);
         require(recoveredAddress != address(0) && recoveredAddress == owner, 'UniswapV2: INVALID_SIGNATURE');
         _approve(owner, spender, value);
     }
 }

 　　　　 require验证截止时间与当前区块时间

　　　　digest 是使用keccak256 得到的哈希值。ecrecover 是solidity内置函数可以获取消息的签名地址。这与就可以与Owner地址对比,就可以验证是否是owner签名的。它允许用户在链下签署授权（approve）的交易，生成任何人都可以使用并提交给区块链的签名。